// Skristal Search, re-written to work under v122 inventory system
// 
// 
// Written by Okasa, with lots of help from Magnels,
//and a f'nom tan'ki to Wisher
//
// "/skri" will perform a search for the selected exile.
// A name may optionally be typed after /skri
//   example:  "/skri" or "/skri mya"

"/skri"
{
	set saveItem @my.right_item
	if saveItem != "skristal"
		"\equip skristal\r"
		
		// pause until the skristal is successfully equipped	
		label skristal_wait
		if @my.right_item == "skristal"
			goto skristal_wait_done
		else
			pause 2
			goto skristal_wait
		end if
		label skristal_wait_done
	end if
	
	if @text == ""
		"/action 's skristal glows showing the image of " @selplayer.name ".\r"
		pause 2
		message "* You begin to search for " @selplayer.name
		pause 2
		"\use " @selplayer.simple_name "\r"
	else
		"/action 's skristal glows showing the image of " @text ".\r"
		pause 2
		message "* You begin to search for " @text
		pause 2
		"\use " @text "\r"
	end if
	
	pause 4

	set counter 0

	label waiting

	set result @env.textLog
	
	if result >= "nothing."
		// This is the case when the skristal returns '... you find nothing.'
		"\action mutters in frustration.\r"
		goto searchOver
	else if result >= "health."
		// This is the case when the skristal returns '... and in good health.'
		"\action raises an eyebrow.\r"
		goto searchOver
	else if result >= "planet."
		// I can vaguely remember getting a message 'so-and-so is on on the planet'
		// This may or may not be right but it doesn't hurt anything to have it here.
		"\action scratches his head.\r"
		goto searchOver
	else if result >= "undertaking."
		"\action appears drained.\r"
		goto searchOver
	else if result >= "existence."
		//This is for 'You are vaguely aware of so-and-so's existence.'
		"\action mutters something about learning a few more of Master Skryss' lessons.\r"
		goto searchOver
	else if result >= "strong sense of"
		"\action shrugs his shoulders.\r"
		goto searchOver
	else if counter > 60
		// This is the case if either the skristal's returned message is not
		// recognized, or if the Mystic has so much Sespos that he is still
		// searching when the counter reaches 30.
		message "* Macro timed out.  You may increase the time limit in the macro."
		goto searchOver
	else
		pause 1
		set counter + 1
	end if

	goto waiting
	
	label searchOver

	if saveItem == "Nothing"
		"/unequip skristal \r"
	else if saveItem != "skristal"
		"/equip \"" saveItem "\"\r"
	end if
	
	message "* Your search has ended."
}