Sync Export Album

Current version: 01
Built on: Aperture 1.5.2
This AppleScript operates on an entire album.


This AppleScript will export all images in a root-level album (where I keep some useful smart albums) into a specific folder. You can change the export settings, source album name, and destination folder by editing the script's properties. Note that p_dstAlias must be an AppleScript alias (you'll get an error otherwise).

Download


-- ---------------------------------------------------------------------------------------------------------
property p_srcAlbumName : "• Desktop Pictures"
property p_exportName : "BTG - JPEG - Fit 2000 x 2000 - Watermark"
property p_dstAlias : alias "BG_MBP2:Work:Digipics - Online:Exports:Desktop Pictures:"

-- ---------------------------------------------------------------------------------------------------------
on run
 tell application "Aperture"
set m_apLibs to libraries
 set m_apLib to item 1 of m_apLibs

set m_apSrcAlb to album p_srcAlbumName of m_apLib
set m_dstFolder to p_dstAlias

my syncAlbum(m_apSrcAlb, m_dstFolder)

end tell
end run



-- ---------------------------------------------------------------------------------------------------------
-- Pass s_srcAlbum as an Aperture album reference
-- Pass s_dstFolder as an alias
on syncAlbum(s_srcAlbum, s_dstFolder)
tell application "Finder"
set s_allExported to name of every file of s_dstFolder
end tell

 tell application "Aperture"
set s_srcImgs to image versions of s_srcAlbum
repeat with s_curImg in (s_srcImgs)
set s_curName to name of s_curImg
set s_curNamePad to (s_curName & ".jpg") as string

 if s_allExported does not contain s_curNamePad then
 log "Must export version"

export {s_curImg} using p_exportName to s_dstFolder

else
 log "Image already exported"

end if
 end repeat
 end tell
end syncAlbum